TR_NecMQ_TadrysRalevenScript
TR_Mainland.esm
Variables
5
Local Variables
TR_Map
NoLore
T_Local_NPC
controlQ
T_Local_NoLore
Source
1Begin TR_NecMQ_TadrysRalevenScript
2
3; this script goes on the head Ordinator in Kulemund and controls the Ordinators there
4; 6+
5
6Short TR_Map
7Short NoLore
8Short T_Local_NPC
9Short controlQ
10short T_Local_NoLore
11
12set TR_Map to 2
13
14if ( MenuMode == 1 )
15 Return
16endif
17
18; if the PC decides to kill the Ordinators, Tadrys has the ring in the inventory
19
20if ( OnDeath == 1 )
21 if ( GetJournalIndex TR_NecMQ_1 >= 30 )
22 if ( GetJournalIndex TR_NecMQ_Outcast < 30 )
23 AddItem TR_NecMQ_RingletOutcast 1
24 endif
25 endif
26endif
27
28; the Ordinators decided to flee from Kulemund and are gone when the PC returns
29
30if ( controlQ == 5 )
31 if ( CellChanged == 1 )
32 if ( GetDisabled == 1 )
33 SetDelete 1
34 else
35 if ( "TR_NecMQ_Llevora Gavin"->GetDisabled == 0 )
36 "TR_NecMQ_Llevora Gavin"->Disable
37 endif
38 if ( "TR_NecMQ_Nathala Sebosi"->GetDisabled == 0 )
39 "TR_NecMQ_Nathala Sebosi"->Disable
40 endif
41 if ( "TR_NecMQ_Ravos Dren"->GetDisabled == 0 )
42 "TR_NecMQ_Ravos Dren"->Disable
43 endif
44 if ( "TR_NecMQ_Sathylos Lland"->GetDisabled == 0 )
45 "TR_NecMQ_Sathylos Lland"->Disable
46 endif
47 if ( GetDisabled == 0 )
48 Disable
49 endif
50 endif
51 endif
52
53elseif ( controlQ == 4 )
54 Return
55
56; if the PC convinces the Ordinators to flee, controlQ is set to 5 from the dialogue window
57; if the Ordinators stay for a while, controlQ is set to 4 from the dialogue window
58
59elseif ( controlQ == 3 )
60 Return
61
62; give a journal entry when the player has calmed down all four of the other Ordinators
63
64elseif ( controlQ == 2 )
65 if ( GetJournalIndex TR_NecMQ_1 >= 40 )
66 if ( TR_NecMQ_CalmOrd > 3 )
67 Journal TR_NecMQ_1 50
68 Set controlQ to 3
69 endif
70 endif
71 Return
72
73; the Ordinators show up after Simine Turethi has sent the PC to find them
74
75elseif ( controlQ == 1 )
76 if ( GetJournalIndex TR_NecMQ_1 >= 30 )
77 if ( GetDisabled == 1 )
78 Enable
79 else
80 Set controlQ to 2
81 endif
82 endif
83
84; the Ordinators are not in Kulemund at the beginning
85
86elseif ( controlQ == 0 )
87 if ( GetDisabled == 0 )
88 Disable
89 else
90 Set controlQ to 1
91 endif
92
93endif
94
95End TR_NecMQ_TadrysRalevenScript