Script
TR_m1_Vero_Renim_sc

TR_Mainland.esm
Variables 9
Local Variables
TR_Map
control
controlQ
NoLore
VvardRank
TargetRank
RankCheck
T_Local_NPC
T_Local_NoLore
Source
  
    Begin TR_m1_Vero_Renim_sc
  
    ;This script is placed on "TR_m1_Vero_Renim", the guy responsible for letting the player join the
  
    ;Mainland Telvanni. This script ensures the player's rank is affected by their Vvardenfel rank, even if
  
    ;they make progress in Vvardenfel after joining Mainland Telvanni.
  
    Short TR_Map
  
    Short control
  
    Short controlQ
  
    Short NoLore
  
    Short VvardRank	;records player's rank in Vvardenfel Telvanni
  
    Short TargetRank	;is the corresponding rank the player should receive in Telvanni
  
    Short RankCheck	;toggle for when the player's rank needs to be increased (check for in dialogue filters)
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    ;standard TR NPC stuff
  
    if ( TR_Map != 1 )
  
    	Set TR_Map to 1
  
    endif
  
    if ( GetPCRank, "Telvanni" == VvardRank )
  
    	Return		;we're only interested in running this script if the player's Vvardenfel Telvanni rank has increased
  
    endif
  
    Set VvardRank to ( GetPCRank, "Telvanni" )	;record the player's new Vvardenfel Telvanni rank
  
    ;this gives the Mainland rank corresponding to each Vvardenfel rank
  
    if ( VvardRank == -1 )			;if player not a member of Vvardenfel Telvanni
  
    	Set TargetRank to -1		;then their corresponding Mainland rank is 'not a member'
  
    elseif ( VvardRank <= 1 )		;if player is Hireling or Retainer in Vvardenfel
  
    	Set TargetRank to 0		;they become Hireling in Mainland
  
    elseif ( VvardRank <= 3 )		;if Oathman or Lawman
  
    	Set TargetRank to 1		;they become Retainer
  
    elseif ( VvardRank <= 5 )		;if Mouth or Spellwright
  
    	Set TargetRank to 2		;they become Oathman
  
    elseif ( VvardRank == 6 )		;if Wizard
  
    	Set TargetRank to 3		;they become Lawman
  
    elseif ( VvardRank <= 8 )		;if Master or Magister
  
    	Set TargetRank to 4		;they become Caster
  
    elseif ( VvardRank == 9 )		;if Archmagister
  
    	Set TargetRank to 5		;they become Spellwright
  
    endif
  
    ;this determines whether the player needs a rank increase on the Mainland
  
    if ( GetPCRank, "Telvanni" >= 0 )						;if player is in Mainland Telvanni
  
    	if ( GetPCRank, "Telvanni" < TargetRank )		;and their rank is lower than the one determined by their Vvardenfel rank
  
    		Set RankCheck to 1									;mark as needing increasing (this will be picked up in dialogue)
  
    	endif
  
    endif
  
    End