Script
TR_m2_Norem_Inte_Vamp2_sc

TR_Mainland.esm
Variables 17
Local Variables
state
done
fightset
cattlekilled
nolore
nohello
noflee
noidle
nointruder
nothief
TR_Map
T_Local_Vampire
control
controlQ
T_Local_NPC
T_Local_NoLore
T_Local_Khajiit
Source
  
    Begin TR_m2_Norem_Inte_Vamp2_sc
  
    ;This script is placed on the vampires "TR_m2_v_Tirandus_Nesca", "TR_m2_v_Zargorynthalen",
  
    ;"TR_m2_v_Khadba_gro-Maga", "and TR_m2_v_Dro_Dato" in Norem, Interior.
  
    ;It makes them attack the 2 outlaws nearby.
  
    Short state
  
    short done
  
    short fightset
  
    short cattlekilled
  
    short nolore
  
    short nohello
  
    short noflee
  
    short noidle
  
    short nointruder
  
    short nothief
  
    short TR_Map
  
    short T_Local_Vampire
  
    short control		;counts the number of dead outlaws
  
    short controlQ
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    short T_Local_Khajiit
  
    if ( controlQ == 1 )
  
    	return
  
    endif
  
    ;this handles the vampires attacking the outlaws
  
    if ( control == 4 )
  
    ;do nothing
  
    elseif ( control == 3 )			;if all three outlaws dead
  
    	Set state to -1			;stop attacking
  
    	Set control to 4
  
    elseif ( state == 0 )										;initially, determine which NPC this script is placed on
  
    	if ( GetPos, x < 3500 )									;NPC is Tirandus Nesca
  
    		Set state to 1										;so toggle to attack Torus Maridus
  
    	elseif ( GetPos, x < 3700 )							;NPC is Zargoryn Thalen
  
    		Set state to 3										;so toggle to attack Torus Maridus
  
    	elseif ( GetPos, x < 4200 )							;NPC is Khadba gro-Magal
  
    		Set state to 3										;so toggle to attack Flings-Scales
  
    	else														;NPC is Dro'Dato
  
    		Set state to 3										;so toggle to attack Staron
  
    	endif
  
    elseif ( state == 1 )													;if toggled to attack Torus Maridus
  
    	StartCombat, "TR_m2_o_Torus_Malidus"					;attack Torus Maridus
  
    	Set state to 2
  
    elseif ( state == 2 )													;if attacking Torus Maridus
  
    	if ( GetDeadCount "TR_m2_o_Torus_Malidus" > 0 )		;if Torus Maridus is dead
  
    		Set control to ( control + 1 )									;note another outlaw dead
  
    		Set state to 3													;toggle to attack Flings-Scales
  
    	endif
  
    elseif ( state == 3 )													;if toggled to attack Flings-Scales
  
    	StartCombat, "TR_m2_o_Flings_Scales"					;attack Flings-Scales
  
    	Set state to 4
  
    elseif ( state == 4 )													;if attacking Flings-Scales
  
    	if ( GetDeadCount "TR_m2_o_Flings_Scales" > 0 )		;if Flings-Scales is dead
  
    		Set control to ( control + 1 )									;note another outlaw dead
  
    		Set state to 5													;toggle to attack Staron
  
    	endif
  
    elseif ( state == 5 )													;if toggled to attack Staron
  
    	StartCombat, "TR_m2_o_Staron"								;attack Staron
  
    	Set state to 6
  
    elseif ( state == 6 )													;if attacking Staron
  
    	if ( GetDeadCount "TR_m2_o_Staron" > 0 )					;if Staron is dead
  
    		Set control to ( control + 1 )									;note another outlaw dead
  
    		Set state to 1													;toggle to attack Torus Maridus
  
    	endif
  
    endif
  
    ;the rest of the script is the standard TR vampire stuff for Aundae vampires
  
    if ( GetJournalIndex "VA_VampHunter" == 110 )
  
    	setFight 100
  
    	setDisposition 0
  
    	set cattlekilled to -1
  
    	return
  
    endif
  
    if ( OnDeath == 1 )
  
    	if ( GetJournalIndex "VA_VampCountess" == 50 )
  
    		if ( VampClan == 1 )
  
    			set VampKills to ( VampKills - 1 )
  
    		elseif ( VampClan == 2 )
  
    			set VampKills to ( VampKills + 1 )
  
    		elseif ( VampClan == 3 )
  
    			set VampKills to ( VampKills + 1 )
  
    		endif
  
    	elseif ( GetJournalIndex "VA_VampAmulet" == 30 )
  
    		if ( VampClan == 1 )
  
    			set VampKills to ( VampKills - 1 )
  
    		elseif ( VampClan == 2 )
  
    			set VampKills to ( VampKills + 1 )
  
    		elseif ( VampClan == 3 )
  
    			set VampKills to ( VampKills + 1 )
  
    		endif
  
    	endif
  
    	AddItem "ingred_vampire_dust_01" 1
  
    	set controlQ to 1
  
       return
  
    endif
  
    if ( done == -1 )
  
    	return
  
    elseif ( done == 0 )
  
    	AddSpell, "Vampire Blood Quarra"	;this is the blood disease
  
    	AddSpell, "Vampire Attributes"
  
    	AddSpell, "Vampire Skills"
  
    	AddSpell, "Vampire Immunities"
  
    	AddSpell, "Vampire Sun Damage"
  
    	AddSpell, "Vampire Touch"
  
    	AddSpell, "Vampire Quarra Specials"
  
    	ModRestoration 75
  
    	set TR_Map to 2
  
    	set done to 1
  
    	set T_Local_Khajiit to -1
  
    	if ( GetRace "T_Els_Cathay" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Cathay-raht" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Dagi-raht" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Ohmes" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Ohmes-raht" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Suthay" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Tojay" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "Khajiit" )
  
    		set T_Local_Khajiit to 1
  
    	endif
  
    endif
  
    if ( control >= 3 )
  
    	if ( done == 1 )		
  
    		;check for PC as a Quarra Vampire
  
    		if ( player->GetSpell "Vampire Quarra Specials" == 1 )
  
    			setfight 30
  
    			set done to 2
  
    		else
  
    			if ( fightset == 0 )
  
    				setfight 90
  
    				setdisposition 20
  
    				set fightset to 1
  
    			endif
  
    		endif
  
    		return
  
    	elseif ( done == 2 )		
  
    		;check for PC NO LONGER a Quarra Vampire
  
    		if ( player->GetSpell "Vampire Quarra Specials" != 1 )
  
    			setfight 90
  
    			setdisposition 20
  
    			set done to -1
  
    		endif
  
    	endif
  
    endif
  
    End