Script
TR_m2_Norem_Sanc_Vamp_sc

TR_Mainland.esm
Variables 17
Local Variables
state
done
fightset
cattlekilled
nolore
nohello
noflee
noidle
nointruder
nothief
TR_Map
T_Local_Vampire
control
controlQ
T_Local_NPC
T_Local_NoLore
T_Local_Khajiit
Source
  
    Begin TR_m2_Norem_Sanc_Vamp_sc
  
    ;This script is placed on the two vampires "TR_m2_v_Darriss" and "TR_m2_v_Grath_gro-Gakk"
  
    ;in Norem, Sanctuary. it makes them fight the two outlaws in the cell. it also includes the
  
    ;standard TR vampire script - these vampires are both Berne
  
    Short state
  
    short done
  
    short fightset
  
    short cattlekilled
  
    short nolore
  
    short nohello
  
    short noflee
  
    short noidle
  
    short nointruder
  
    short nothief
  
    short TR_Map
  
    short T_Local_Vampire
  
    short control		;counts number of dead outlaws
  
    short controlQ
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    short T_Local_Khajiit
  
    if ( controlQ == 1 )
  
    	return
  
    endif
  
    ;this handles the vampires attacking the outlaws
  
    if ( control == 3 )
  
    ;do nothing
  
    elseif ( control == 2 )			;if both outlaws dead
  
    	Set state to -1			;stop attacking
  
    	Set control to 3			;and reset
  
    elseif ( state == 0 )												;initially, determine which NPC this script is placed on
  
    	if ( GetPos, x > 4200 )									;NPC is Darriss
  
    		Set state to 1										;so toggle to attack Martia Velurius
  
    	else														;NPC is Grath gro-Gakk
  
    		Set state to 3										;so toggle to attack Herma Homeless
  
    	endif
  
    elseif ( state == 1 )													;if toggled to attack Martia Velurius
  
    	StartCombat, "TR_m2_o_Martia_Velurius"					;attack Martia Velurius
  
    	Set state to 2
  
    elseif ( state == 2 )													;if attacking Martia Velurius
  
    	if ( GetDeadCount "TR_m2_o_Martia_Velurius" > 0 )		;if Martia Velurius is dead
  
    		Set control to ( control + 1 )									;note another outlaw dead
  
    		Set state to 3													;toggle to attack Herma Homeless
  
    	endif
  
    elseif ( state == 3 )													;if toggled to attack Herma Homeless
  
    	StartCombat, "TR_m2_o_Herma_Homeless"				;attack Herma Homeless
  
    	Set state to 4
  
    elseif ( state == 4 )													;if attacking Herma Homeless
  
    	if ( GetDeadCount "TR_m2_o_Herma_Homeless" > 0 )	;if Herma Homeless is dead
  
    		Set control to ( control + 1 )									;note another outlaw dead
  
    		Set state to 1													;toggle to attack Martia Velurius
  
    	endif
  
    endif
  
    ;rest of the script is standard TR vampire stuff
  
    if ( GetJournalIndex "VA_VampHunter" == 110 )
  
    	setFight 100
  
    	setDisposition 0
  
    	set cattlekilled to -1
  
    	return
  
    endif
  
    if ( OnDeath == 1 )
  
    	if ( GetJournalIndex "VA_VampCountess" == 50 )
  
    		if ( VampClan == 1 )
  
    			set VampKills to ( VampKills - 1 )
  
    		elseif ( VampClan == 2 )
  
    			set VampKills to ( VampKills + 1 )
  
    		elseif ( VampClan == 3 )
  
    			set VampKills to ( VampKills + 1 )
  
    		endif
  
    	elseif ( GetJournalIndex "VA_VampAmulet" == 30 )
  
    		if ( VampClan == 1 )
  
    			set VampKills to ( VampKills - 1 )
  
    		elseif ( VampClan == 2 )
  
    			set VampKills to ( VampKills + 1 )
  
    		elseif ( VampClan == 3 )
  
    			set VampKills to ( VampKills + 1 )
  
    		endif
  
    	endif
  
    	AddItem "ingred_vampire_dust_01" 1
  
    	set controlQ to 1
  
    	return
  
    endif
  
    if ( done == -1 )
  
    	return
  
    elseif ( done == 0 )
  
    	AddSpell, "Vampire Blood Quarra"	;this is the blood disease
  
    	AddSpell, "Vampire Attributes"
  
    	AddSpell, "Vampire Skills"
  
    	AddSpell, "Vampire Immunities"
  
    	AddSpell, "Vampire Sun Damage"
  
    	AddSpell, "Vampire Touch"
  
    	AddSpell, "Vampire Quarra Specials"
  
    	ModRestoration 75
  
    	set TR_Map to 2
  
    	set done to 1
  
    	set T_Local_Khajiit to -1
  
    	if ( GetRace "T_Els_Cathay" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Cathay-raht" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Dagi-raht" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Ohmes" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Ohmes-raht" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Suthay" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "T_Els_Tojay" )
  
    		set T_Local_Khajiit to 1
  
    	elseif ( GetRace "Khajiit" )
  
    		set T_Local_Khajiit to 1
  
    	endif
  
    endif
  
    if ( control >= 2 )
  
    	if ( done == 1 )		
  
    		;check for PC as a Quarra Vampire
  
    		if ( player->GetSpell "Vampire Quarra Specials" == 1 )
  
    			setfight 30
  
    			set done to 2
  
    		else
  
    			if ( fightset == 0 )
  
    				setfight 90
  
    				setdisposition 20
  
    				set fightset to 1
  
    			endif
  
    		endif
  
    		return
  
    	elseif ( done == 2 )		
  
    		;check for PC NO LONGER a Quarra Vampire
  
    		if ( player->GetSpell "Vampire Quarra Specials" != 1 )
  
    			setfight 90
  
    			setdisposition 20
  
    			set done to -1
  
    		endif
  
    	endif
  
    endif
  
    End