Script
TR_m2_q_35_vampires

TR_Mainland.esm
Variables 17
Local Variables
done
fightset
cattlekilled
nolore
nohello
noflee
noidle
nointruder
nothief
TR_Map
T_Local_Vampire
control
controlQ
bribefail
enabled
T_Local_NPC
T_Local_NoLore
Source
  
    begin TR_m2_q_35_vampires
  
    ;Vampire outcasts, of Berne blood
  
    ;Only appear in Mugan Crypt when quest Interview with a Vampire is started
  
    ;They don't count as Berne vampires for non-agressivity or vanilla quest deathcounts
  
    ;Local variable "cattlekilled" needs to stay, as it is used to identify vampires
  
    ;local "fightset" also, used by mods same reason
  
    ;Script uses these NPCs' levels:
  
    ;TR_m2_q_35_vampire2
  
    ;TR_m2_q_35_vampire3
  
    ;TR_m2_q_35_vampire4
  
    ;to separate them and notify the script on Vampire1 when one dies.
  
    short done
  
    short fightset
  
    short cattlekilled
  
    short nolore
  
    short nohello
  
    short noflee
  
    short noidle
  
    short nointruder
  
    short nothief
  
    short TR_Map
  
    short T_Local_Vampire
  
    short control
  
    short controlQ
  
    short bribefail	;doonce for too-specific bribefail answers
  
    short enabled
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    if ( enabled == 0 )
  
    	If ( GetJournalIndex "TR_m2_MG_Ranosa2" > 0 )
  
    		Enable
  
    		set enabled to 1
  
    	ElseIf ( GetDisabled == 0 )
  
    		Disable
  
    	Endif
  
    endif
  
    if ( OnDeath == 1 )
  
    	AddItem "ingred_vampire_dust_01" 1
  
    	set TR_m2_q_35_dead to ( TR_m2_q_35_dead + 1 )		;global for dead vampires
  
    	If ( GetLevel == 6 )													;stop checking whether it's attacking in the leader's script once it's dead
  
    		set TR_m2_q_35_Vampire1.Vampire2dead to 1
  
    	ElseIf ( GetLevel == 5 )
  
    		set TR_m2_q_35_Vampire1.Vampire3dead to 1
  
    	ElseIf ( GetLevel == 7 )
  
    		set TR_m2_q_35_Vampire1.Vampire4dead to 1
  
    	Endif
  
    endif
  
    ; Berne blood & regional topic filter
  
    if ( done == 0 )
  
    	AddSpell "Vampire Blood Berne"	;this is the blood disease
  
    	AddSpell "Vampire Attributes"
  
    	AddSpell "Vampire Skills"
  
    	AddSpell "Vampire Immunities"
  
    	AddSpell "Vampire Sun Damage"
  
    	AddSpell "Vampire Touch"
  
    	AddSpell "Vampire Berne Specials"
  
    	ModRestoration 75
  
    	set TR_Map to 2
  
    	set done to 1
  
    endif
  
    end