Script
TR_m2_q_9_VilynScript

TR_Mainland.esm
Variables 10
Local Variables
distcheck
trackmove
TR_Map
control
controlQ
T_Local_NPC
NoLore
Timer_A
Timer_B
Timer_C
Source
  
    Begin TR_m2_q_9_VilynScript
  
    ;this is the local script on Vilyn Avani for the Flin Galore! quest.
  
    ;It handles Vilyn's movement and checking whether the player is caught following him
  
    Short distcheck		;toggles checking whether player is caught peeking (0 = not caught, -1 = caught, more than 1 = checking)
  
    Short trackmove 	;tracks the progress of movement
  
    Float Timer_A		;timer for distcheck
  
    Float Timer_B		;timer for trackmove
  
    Float Timer_C		;timer for preventing Vilyn getting stuck (bug prevention)
  
    short TR_Map
  
    short control
  
    short controlQ
  
    short T_Local_NPC
  
    short NoLore
  
    ;standard map2 npc clause
  
    if ( TR_Map != 2 )
  
    	Set TR_Map to 2
  
    endif
  
    ;don't run in menu mode
  
    if ( menumode )
  
    	return
  
    endif
  
    ;rest of the script only runs when Vilyn leaves his shack - this is triggered from the global script TR_m2_q_9_FlinGaloreGlobal
  
    if ( GetPCCell "Andar Mok, Vilyn Avani's Shack" )
  
    	return
  
    endif
  
    ;this block deals with Vilyn checking to see if the player is following (checks every 2 seconds)
  
    if ( distcheck == 1 )
  
    	Set Timer_A to ( Timer_A + GetSecondsPassed )	;count seconds
  
    	if ( Timer_A > 2 )											;if 2 seconds passed
  
    		Set Timer_A to 0										;reset timer
  
    		Set distcheck to 2										;check conditions
  
    	endif
  
    elseif ( distcheck == 2 )
  
    	if ( GetDistance "player" < 1000 )						;player is close enough to be caught
  
    		set distcheck to 3
  
    	else
  
    		set distcheck to 1										;player isn't close, start counting again
  
    	endif
  
    elseif ( distcheck == 3 )
  
    	if ( GetDetected, player )									;player is detected
  
    		Set distcheck to 4
  
    	else
  
    		set distcheck to 1										;player isn't detected, start counting again
  
    	endif
  
    elseif ( distcheck == 4 )
  
    	if ( GetLOS, player )										;player can be seen
  
    		Set distcheck to 5
  
    	else
  
    		Set distcheck to 1										;player can't be seen, start counting again
  
    	endif
  
    elseif ( distcheck == 5 )										;now Vilyn has caught the player
  
    	if ( GetForceSneak )
  
    		ClearForceSneak										;stop Vilyn sneaking
  
    	endif
  
    	Set distcheck to 6
  
    	AiWander, 0, 0, 0											;stop
  
    elseif ( distcheck == 6 )
  
    	Set Timer_A to ( Timer_A + GetSecondsPassed )
  
    	if ( Timer_A > 2 )											;wait for 2 seconds
  
    		Set Timer_A to 0
  
    		Set distcheck to 7
  
    		if ( GetDistance "player" < 300 )					;if the player is very near
  
    			ForceGreeting										;force greet
  
    			Return
  
    		endif
  
    	endif
  
    elseif ( distcheck == 7 )
  
    	Set distcheck to -1											;stop checking and remember player was caught
  
    	if ( GetJournalIndex "TR_m2_AO_FlinGalore" < 55 )
  
    		Journal TR_m2_AO_FlinGalore 55
  
    	else
  
    		MessageBox "Vilyn appears to have seen you."
  
    	endif
  
    	Set trackmove to ( trackmove - 1 )						;give Vilyn his AITravel instructions again
  
    endif
  
    ;prevents AI being modified by rest of script executing
  
    if ( distcheck >= 4 )
  
    	return
  
    endif
  
    ;this block deals with performing the movement
  
    if ( trackmove == 0 )
  
    	disable															;disable (for bug fix)
  
    	Set trackmove to 1
  
    	Set "TR_m2_q_9_FlinGaloreGlobal".vilynvar to -1	;note that walk has begun ( Global script then prevents repeat that night)
  
    elseif ( trackmove == 1 )
  
    	enable															;enable (for bug fix)
  
    	set trackmove to 2
  
    	Set distcheck to 0												;don't check for player following yet
  
    	SetHello, 0														;don't greet the player
  
    	AiTravel, 267825, -4577, 157, 1							;walk down from platform
  
    elseif ( trackmove == 2 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 3
  
    	endif
  
    elseif ( trackmove == 3 )
  
    	AiTravel, 267065, -4372, 157, 1							;walk to village center
  
    	Set trackmove to 4
  
    elseif ( trackmove == 4 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 5
  
    	endif
  
    elseif ( trackmove == 5 )
  
    	Set Timer_B to ( Timer_B + GetSecondsPassed )		;wait for 2 seconds
  
    	if ( Timer_B > 2 )
  
    		Set Timer_B to 0
  
    		Set trackmove to 6
  
    	endif
  
    elseif ( trackmove == 6 )
  
    	AiTravel, 265782, -4628, 252, 1							;walk towards field
  
    	Set trackmove to 7
  
    elseif ( trackmove == 7 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 8
  
    	endif
  
    elseif ( trackmove == 8 )
  
    	AiTravel, 265491, -5202, 252, 1							;walk behind Dreynis Teran's shack
  
    	Set trackmove to 9
  
    elseif ( trackmove == 9 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 10
  
    	endif
  
    elseif ( trackmove == 10 )
  
    	Set Timer_B to ( Timer_B + GetSecondsPassed )		;wait for 3 seconds
  
    	if ( Timer_B > 3 )
  
    		Set Timer_B to 0
  
    		Set trackmove to 11
  
    		if ( distcheck != -1 )										;if not already shouted at player,
  
    			Set distcheck to 1										;start to check for player following
  
    		endif
  
    	endif
  
    elseif ( trackmove == 11 )
  
    	if ( distcheck != -1 )											;if not already caught,
  
    		ForceSneak													;start sneaking
  
    	endif
  
    	AiTravel, 265928, -5393, 131, 1							;go behind Dreynis's shack
  
    	Set trackmove to 12
  
    elseif ( trackmove == 12 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 13
  
    	endif
  
    elseif ( trackmove == 13 )
  
    	AiTravel, 266126, -5746, 216, 1							;go towards rocks
  
    	Set trackmove to 14
  
    elseif ( trackmove == 14 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 15
  
    	endif
  
    elseif ( trackmove == 15 )
  
    	AiTravel, 267126, -5670, 216, 1							;go past Andilo Vadryon's shack
  
    	Set trackmove to 16
  
    elseif ( trackmove == 16 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 17
  
    		ClearForceSneak											;stop sneaking
  
    	endif
  
    elseif ( trackmove == 17 )
  
    	Set Timer_B to ( Timer_B + GetSecondsPassed )		;wait for 3 seconds
  
    	if ( Timer_B > 3 )
  
    		Set Timer_B to 0
  
    		Set trackmove to 18
  
    	endif
  
    elseif ( trackmove == 18 )
  
    	if ( distcheck != -1 )											;if not caught by player
  
    		ForceSneak													;start sneaking again
  
    	endif
  
    	AiTravel, 267874, -5766, 195, 1							;go behind Vilyn's shack
  
    	Set trackmove to 19
  
    elseif ( trackmove == 19 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 20
  
    	endif
  
    elseif ( trackmove == 20 )
  
    	AiTravel, 268659, -5380, 263, 1							;go towards rocks
  
    	Set trackmove to 21
  
    elseif ( trackmove == 21 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 22
  
    		ClearForceSneak											;stop sneaking
  
    	endif
  
    elseif ( trackmove == 22 )
  
    	Set Timer_B to ( Timer_B + GetSecondsPassed )		;wait for 2 seconds
  
    	if ( Timer_B > 2 )
  
    		Set Timer_B to 0
  
    ;		MessageBox "He should split paths here."
  
    		if ( distcheck == -1 )										;if caught by the player
  
    			Set trackmove to 33									;head home
  
    		else															;otherwise
  
    			Set trackmove to 23									;head for the barrel
  
    		endif
  
    	endif
  
    elseif ( trackmove == 23 )							;this section continues towards the hidden Flin
  
    	if ( distcheck != -1 )											;if not caught by player
  
    		ForceSneak													;start sneaking again
  
    	endif
  
    	AiTravel, 269703, -5408, 308, 1							;go towards treestump
  
    	Set trackmove to 24
  
    elseif ( trackmove == 24 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 25
  
    	endif
  
    elseif ( trackmove == 25 )
  
    	AiTravel, 270356, -4885, 328, 1							;go around rocks
  
    	Set trackmove to 26
  
    elseif ( trackmove == 26 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		if ( distcheck == -1 )										;if caught by the player
  
    			Set trackmove to 31									;head home
  
    		else															;otherwise
  
    			Set trackmove to 27									;keep heading for the barrel
  
    		endif
  
    	endif
  
    elseif ( trackmove == 27 )						;this section continues towards the hidden Flin
  
    	AiTravel, 270635, -4990, 328, 1							;sneak to hidden barrel
  
    	Set trackmove to 28
  
    elseif ( trackmove == 28 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 29
  
    	endif
  
    elseif ( trackmove == 29 )
  
    	Set Timer_B to ( Timer_B + GetSecondsPassed )		;wait for 8 seconds
  
    	if ( Timer_B > 8 )
  
    		Set Timer_B to 0
  
    		Set trackmove to 31
  
    	endif
  
    elseif ( trackmove == 31 )						;from here is the return journey
  
    	AiTravel, 269224, -4618, 272, 1							;go back towards village
  
    	Set trackmove to 32
  
    elseif ( trackmove == 32 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 33
  
    		if ( GetForceSneak )
  
    			ClearForceSneak										;stop sneaking
  
    			Set distcheck to 0										;stops checking for player following (if he still was)
  
    		endif
  
    	endif
  
    elseif ( trackmove == 33 )						;this is the shortcut to the return journey
  
    	AiTravel, 268656, -4671, 209, 1							;go further towards village
  
    	Set trackmove to 34
  
    elseif ( trackmove == 34 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 35
  
    	endif
  
    elseif ( trackmove == 35 )
  
    	AiTravel, 267799, -4531, 164, 1							;walk back to platform outside shack
  
    	Set trackmove to 36
  
    elseif ( trackmove == 36 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		Set trackmove to 37
  
    	endif
  
    elseif ( trackmove == 37 )
  
    	AiTravel, 268046, -4893, 249, 1							;walk to door
  
    	Set trackmove to 38
  
    elseif ( trackmove == 38 )
  
    	if ( GetAIPackageDone )										;wait for him to get there
  
    		SetHello, 30
  
    		Set trackmove to 0																		;reset trackmove
  
    		Set Timer_A to 0
  
    		Set Timer_B to 0																			;reset all the timers
  
    		Set Timer_C to 0
  
    		PositionCell, -438, -489, -111, 132, "Andar Mok, Vilyn Avani's Shack"		;go back into shack
  
    		AiWander 0 0 0 0 0 0 0 0 0 0 0 0
  
    		Set "TR_m2_q_9_FlinGaloreGlobal".vilynvar to -1								;prevents bug
  
    	endif
  
    endif
  
    ;This block prevents bugs with Vilyn getting stuck / forgetting where he should be going
  
    if ( GetCurrentAIPackage <= 0 )								;if Vilyn is idle
  
    	Set Timer_C to ( Timer_C + GetsecondsPassed )
  
    	if ( Timer_C > 10 )											;for more than 10 seconds (should only happen if something's gone wrong)
  
    		Set trackmove to ( trackmove - 1 )					;give him his last AITravel orders again
  
    		if ( trackmove == 30 )									;since there is no stage 30 -- arvisrend
  
    			set trackmove to 29
  
    		endif
  
    		Set Timer_C to 0										;reset timer
  
    	endif
  
    else
  
    	if ( Timer_C > 0 )											;if nothing's going wrong
  
    		Set Timer_C to 0										;reset timer
  
    	endif
  
    endif
  
    End