Script
TR_m2_q_A8_5_Dras_Varethi

TR_Mainland.esm
Variables 7
Local Variables
NoLore
killedbyscript
spelltaught
control
T_Local_NPC
T_Local_NoLore
TR_Map
Source
  
    Begin TR_m2_q_A8_5_Dras_Varethi
  
    Short NoLore
  
    Short killedbyscript	; killed by Midave Llarys raid from Erethan
  
    Short spelltaught		; =1 if player bought spell
  
    Short control			; =1 if told PC comes from Erethan
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    short TR_Map
  
    if ( TR_Map != 2 )
  
    	set TR_Map to 2
  
    endif
  
    if ( killedbyscript == 1 )
  
    	if ( CellChanged == 1 )
  
    		if ( GetDeadCount "TR_m2_Midave_Llarys" < 1 )
  
    			SetHealth -5
  
    			RemoveItem "flameeater robe" 1
  
    			RemoveItem "T_Com_Adamant_Dagger_01" 1
  
    			TR_m2_Midave_Llarys->AddItem "T_Com_Adamant_Dagger_01" 1
  
    			if ( GetDeadCount "TR_m2_q_A8_5_guard" < 1 )
  
    				TR_m2_q_A8_5_guard->Disable
  
    			endif
  
    			set killedbyscript to 2
  
    		endif
  
    	endif
  
    elseif ( killedbyscript == 2 )
  
    	if ( GetDistance Player < 1024 )
  
    		if ( GetJournalIndex TR_m2_A8_5_FreeAtLast < 125 ) 
  
    			Journal TR_m2_A8_5_FreeAtLast2 130		;FreeAtLast2 is a different journal ID so as not to interfere with other results
  
    		else
  
    			Journal TR_m2_A8_5_FreeAtLast2 131		;if shamirr was brought by player
  
    		endif
  
    		set killedbyscript to 3
  
    	endif
  
    elseif ( killedbyscript == 0 )
  
    	if ( OnDeath == 1 )
  
    		if ( GetJournalIndex TR_m2_A8_5_FreeAtLast <= 115 ) 
  
    			Journal TR_m2_A8_5_FreeAtLast 70
  
    		endif
  
    	endif
  
    	if ( GetJournalIndex TR_m2_A8_5_FreeAtLast < 30 )
  
    		if ( GetJournalIndex TR_m2_A8_5_FreeAtLast != 10 )		;allow finding him without asking Pedivur
  
    			if ( GetDisabled == 0 )
  
    				Disable
  
    				TR_m2_q_A8_5_passive1->Disable
  
    				TR_m2_q_A8_5_passive2->Disable
  
    			endif
  
    		endif
  
    	elseif ( GetJournalIndex TR_m2_A8_5_FreeAtLast == 30 )
  
    		if ( GetDistance Player < 512 )
  
    			ForceGreeting
  
    		endif
  
    	elseif ( GetJournalIndex TR_m2_A8_5_FreeAtLast == 45 )
  
    		set killedbyscript to 1
  
    	elseif ( GetJournalIndex TR_m2_A8_5_FreeAtLast == 55 )	;in this case stage may become 115 by finding shamirr's corpse: variable directly set by dialogue
  
    		set killedbyscript to 1
  
    	elseif ( GetJournalIndex TR_m2_A8_5_FreeAtLast == 65 )
  
    		set killedbyscript to 1
  
    	elseif ( GetJournalIndex TR_m2_A8_5_FreeAtLast == 123 )
  
    		set killedbyscript to 1												;will also be set to be killed by stage 125-126 if still alive
  
    	endif
  
    endif
  
    end