Script
TR_m2_q_TheRiftMage

TR_Mainland.esm
Variables 11
Local Variables
clockStart
towerWalk
cantTalk
walkDay
riftOpen
T_Local_NPC
NoLore
TR_Map
T_Local_NoLore
timer
walkHour
Source
  
    begin TR_m2_q_TheRiftMage
  
    ; ai behavior for Ralam Othravel
  
    float timer
  
    short clockStart
  
    short towerWalk
  
    short cantTalk
  
    short walkDay
  
    float walkHour
  
    short riftOpen
  
    short T_Local_NPC
  
    short NoLore
  
    short TR_Map
  
    short T_Local_NoLore
  
    if ( MenuMode == 1 )
  
        return
  
    endif
  
    if ( clockStart == 1 )
  
    	set timer to ( timer + GetSecondsPassed )
  
    endif
  
    ; start the walk to the tower when dialogue sets variable
  
    if ( towerWalk == 1 )
  
    	set cantTalk to 1
  
    	set walkDay to DaysPassed
  
    	set walkHour to GameHour
  
    	; casts Water Walking on self to cross river
  
    	Cast "Water Walking" "TR_m2_Ralam_Othravel"
  
    	AITravel 297280 10635 37 1 ; TR_m2_MARK_Ralam
  
    	set towerWalk to 2
  
    ; Ralam walks to ritual chamber after the player accepts the
  
    ; quest, also puts on helmet
  
    elseif ( towerWalk == 7 )
  
    	if ( GetJournalIndex "TR_m2_wil_TheRift" >= 20 )
  
    		set cantTalk to 1
  
    		set walkDay to DaysPassed
  
    		set walkHour to GameHour
  
    		AITravel 6203 3318 14563 1 ; TR_m2_MARK_Ralam
  
    		AddItem "dust_adept_helm" 1
  
    		set towerWalk to 8
  
    	endif
  
    endif
  
    ; change behavior whenever a travel is complete
  
    if ( towerWalk == 2 )
  
    	if ( getDistance TR_m2_q_TheRiftDest1 < 100 )
  
    		AITravel 297922 10257 265 1 ; TR_m2_MARK_Ralam
  
    		set towerWalk to 3
  
    	endif
  
    elseif ( towerWalk == 3 )
  
    	if ( getDistance TR_m2_q_TheRiftDest2 < 100 )
  
    		AITravel 298851 12187 266 1 ; TR_m2_MARK_Ralam
  
    		set towerWalk to 4
  
    	endif
  
    elseif ( towerWalk == 4 )
  
    	if ( getDistance TR_m2_q_TheRiftDest3 < 100 )
  
    		; enter the tower
  
    		"TR_m2_q_TheRiftTowerDoor"->unlock
  
    		"TR_m2_q_TheRiftTowerDoor"->PlaySound3D, "Door Heavy Open"
  
    		PositionCell 4216 2516 15073 5400 "Ald Volos" ; TR_m2_MARK_Ralam
  
    		AITravel 5854 2880 15072 1 ; TR_m2_MARK_Ralam
  
    		set towerWalk to 5
  
    	endif
  
    elseif ( towerWalk == 5 )
  
    	if ( getDistance TR_m2_q_TheRiftDest4 < 100 )
  
    		AITravel 5339 3096 15327 1 ; TR_m2_MARK_Ralam
  
    		set towerWalk to 6
  
    	endif
  
    elseif ( towerWalk == 6 )
  
    	if ( getDistance TR_m2_q_TheRiftDest5 < 100 )
  
    		; made it to the tower's dome
  
    		set cantTalk to 0
  
    		SetAngle Z 45
  
    		AIWander 0 5 0 60 20 20 20
  
    		set towerWalk to 7
  
    	endif
  
    elseif ( towerWalk == 8 )
  
    	if ( getDistance TR_m2_q_TheRiftDest6 < 100 )
  
    		; arrived at ritual chamber
  
    		set cantTalk to 0
  
    		SetAngle Z 135
  
    		AIWander 0 5 0 60 20 20 20
  
    		set towerWalk to 9
  
    	endif
  
    endif
  
    ; if player waits, complete AITravel
  
    if ( towerWalk >= 1 )
  
    	if ( towerWalk <= 6 )
  
    		if ( DaysPassed > walkDay )
  
    			set walkHour to ( walkHour - 24 )
  
    			set walkDay to DaysPassed
  
    		endif
  
    		if ( GameHour >= walkHour + 1 )
  
    			"TR_m2_q_TheRiftTowerDoor"->unlock
  
    			set cantTalk to 0
  
    			PositionCell 5339 3096 15327 2700 "Ald Volos" ; TR_m2_MARK_Ralam
  
    			AIWander 0 5 0 60 20 20 20
  
    			set towerWalk to 7
  
    		endif
  
    	endif
  
    endif
  
    if ( towerWalk == 8 )
  
    	if ( DaysPassed > walkDay )
  
    		set walkHour to ( walkHour - 24 )
  
    		set walkDay to DaysPassed
  
    	endif
  
    	if ( GameHour >= walkHour + 1 )
  
    		set cantTalk to 0
  
    		PositionCell 6203 3318 14563 9000 "Ald Volos" ; TR_m2_MARK_Ralam
  
    		AIWander 0 5 0 60 20 20 20
  
    		set towerWalk to 9
  
    	endif
  
    endif
  
    ; activates the rift portal and disappears
  
    if ( GetJournalIndex "TR_m2_wil_TheRift" == 70 )
  
    	if ( towerWalk != 9 )
  
    	elseif ( riftOpen == 0 )
  
    		set cantTalk to 1
  
    		AiTravel 5757 3031 14598 1 ; TR_m2_MARK_Ralam
  
    		;PlaySound "shock area"
  
    		SetHealth 10000
  
    		set riftOpen to 1
  
    	elseif ( riftOpen == 1 )
  
    		if ( getDistance TR_m2_q_TheRiftDest7 < 50 )
  
    			Cast "Chameleon" "TR_m2_Ralam_Othravel"
  
    			StartScript "TR_m2_q_TheRiftHappening"
  
    			startscript TR_m2_q_TheRiftBk
  
    			set clockStart to 1
  
    			set riftOpen to 2
  
    		endif
  
    	elseif ( riftOpen == 2 )
  
    		if ( timer > 1 )
  
    			"TR_m2_TheRiftCaster"->Cast "Lightning Bolt" "TR_m2_Ralam_Othravel"
  
    			set riftOpen to 3
  
    		endif
  
    	elseif ( riftOpen == 3 )
  
    		if ( timer > 2 )
  
    			"TR_m2_TheRiftCaster"->Cast "Lightning Bolt" "TR_m2_Ralam_Othravel"
  
    			set riftOpen to 4
  
    		endif
  
    	elseif ( riftOpen == 4 )
  
    		if ( timer > 3 )
  
    			"TR_m2_TheRiftCaster"->Cast "Lightning Bolt" "TR_m2_Ralam_Othravel"
  
    			set riftOpen to 5
  
    		endif
  
    	elseif ( riftOpen == 5 )
  
    		if ( timer > 4 )
  
    			FadeOut 1.0
  
    			PlaySound "shock area"
  
    			PlaceAtMe sprigganup 1 1 1 ; visual effect
  
    			PlaySound "Windbag"
  
    			PlaySound "endboom3"
  
    			SetChameleon 100
  
    			set riftOpen to 6
  
    		endif
  
    	elseif ( riftOpen == 6 )
  
    		if ( timer > 6 )
  
    			FadeIn 1.0
  
    			Journal "TR_m2_wil_TheRift" 75
  
        		set riftOpen to 7
  
    			disable
  
    		endif
  
    	endif
  
    endif
  
    if ( OnDeath == 1 )
  
    	if ( ScriptRunning "TR_m2_q_TheRiftHappening" )
  
    		return
  
    	endif
  
    	if ( GetJournalIndex "TR_m2_wil_TheRift" >= 20 )
  
    		if ( GetJournalIndex "TR_m2_wil_TheRift" != 40 )
  
    			Journal "TR_m2_wil_TheRift" 65
  
    			set riftOpen to -1
  
    			set clockStart to 0
  
    		endif
  
    	endif
  
    endif
  
    if ( TR_Map )
  
        return
  
    endif
  
    set TR_Map to 2
  
    End