Script
TR_m3_NPC_YontusKushummu

TR_Mainland.esm
Variables 20
Local Variables
TR_Map
control
controlQ
NoLore
T_Local_NPC
T_Local_NoLore
nohit
noattack
nothief
nointruder
noidle
noflee
nohello
sick
state
done
messageOn
button
doOnce
timer
Source
  
    Begin TR_m3_NPC_YontusKushummu
  
    ; Yontus Kushummu is a valued client of the East Empire Company on the eastern Aanthirin.
  
    ; He makes two appearances in the OE EEC Cano questline:
  
    ; Q2: He shows up at the front desk with his slave in tow.
  
    ; Q6: He and his slave are being held hostage by a smuggler in a cave.
  
    ; He is disabled by default, enabled for Q2, disabled again, PositionCell'd around, reenabled for Q6.
  
    ; This local script does the enable/disable.
  
    ; This local script also models how, in Q6, his tongue gets cut out. He's a very unpleasant person.
  
    ; Note for the future: He has Corpses Persist enabled because in one outcome for Q6, you have to
  
    ; activate his corpse to progress. Without that ticked, his corpse might despawn after 3 days
  
    ; and the player might be softlocked.
  
    short TR_Map
  
    short control
  
    short controlQ
  
    short NoLore
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    short nohit
  
    short noattack
  
    short nothief
  
    short nointruder
  
    short noidle
  
    short noflee
  
    short nohello
  
    short sick
  
    ;global TR_m3_EEC_YontusFreed ;0 by default, 1 when goes free
  
    if ( MenuMode )
  
    	return
  
    endif
  
    if ( TR_Map != 3 )
  
    	set TR_Map to 3
  
    	disable
  
    	; initially set nohit, noattack, etc. to 1 -- this, counterintuitively, makes it so that they have no effect
  
    	set nohit to 1
  
    	set noattack to 1
  
    	set nothief to 1
  
    	set nointruder to 1
  
    	set noidle to 1
  
    	set noflee to 1
  
    	set nohello to 1
  
    endif
  
    if ( GetJournalIndex "TR_m3_EEC_Cano2" >= 100 )
  
    	if ( GetJournalIndex "TR_m3_EEC_Cano2" < 120 )
  
    		short state
  
    		if ( state == -1 )
  
    			disable
  
    			set state to -10
  
    		elseif ( CellChanged )
  
    			set state to -1
  
    		elseif ( state == 0 )
  
    			AITravel -160 80 5 1 ;walking to the door...
  
    			set state to 1
  
    		elseif ( state == 1 )
  
    			if ( GetAIPackageDone )
  
    				set state to 2
  
    			endif
  
    		elseif ( state == 2 )
  
    			float timer
  
    			if ( timer < 0.5 )
  
    				set timer to timer + GetSecondsPassed
  
    			else
  
    				PlaySound3D "Door Heavy Open"
  
    				set state to -1
  
    			endif
  
    		endif
  
    	endif
  
    endif
  
    if ( OnDeath )
  
    	if ( GetJournalIndex "TR_m3_EEC_Cano2" < 200 )
  
    		Journal "TR_m3_EEC_Cano2" 300
  
    		PCExpell "East Empire Company"
  
    		"TR_m3_Yak gro-Yam"->Disable
  
    	elseif ( GetJournalIndex "TR_m3_EEC_Cano6" < 200 )
  
    		if ( TR_m3_EEC_RansomRequested ) ;implies TR_m3_EEC_Cano6 > 0
  
    			Journal "TR_m3_EEC_Cano6" 150
  
    		endif
  
    	endif
  
    endif
  
    short done
  
    short messageOn
  
    if ( sick )
  
    	if ( done == 0 )
  
    		if ( GetHealth < 1 )
  
    			SetParalysis 0
  
    			SetFatigue 0
  
    			set done to 1
  
    			return
  
    		endif
  
    		setfatigue -200
  
    		if ( GetParalysis == 0 )
  
    			SetParalysis 0
  
    		elseif ( Random100 > 66 )
  
    			SetParalysis 0
  
    		endif
  
    	elseif ( OnActivate )
  
    		Activate
  
    	endif
  
    	if ( OnActivate )
  
    		if ( GetPCSneaking )
  
    			Activate
  
    		else
  
    			set messageOn to 1
  
    		endif
  
    	endif
  
    	if ( messageOn == 1 )
  
    		if ( "Player"->GetItemCount "gold_001" >= 100 )
  
    			MessageBox "Yontus Kushummu is unconscious.", "Leave him 100 drakes", "Let him be"
  
    			set messageOn to 2
  
    		else
  
    			MessageBox "Yontus Kushummu is unconscious."
  
    			set messageOn to 0
  
    		endif
  
    	endif
  
    	if ( messageOn == 2 )
  
    		short button
  
    		set button to GetButtonPressed
  
    		if ( button == 0 )
  
    			"Player"->RemoveItem "gold_001" 100
  
    			AddItem "gold_001" 100
  
    			set messageOn to 0
  
    		elseif ( button == 1 )
  
    			set messageOn to 0
  
    		endif
  
    	endif
  
    endif
  
    if ( OnActivate )
  
    	AddTopic "Yontus Kushummu"
  
    	Activate
  
    	if ( GetJournalIndex "TR_m3_EEC_Cano6" > 0 )
  
    		if ( TR_m3_EEC_RansomRequested == 0 )
  
    			Journal "TR_m3_EEC_Cano6_c" 290 ;rest in peace
  
    		endif
  
    	endif
  
    endif
  
    if ( TR_m3_EEC_RansomRequested == 0 )
  
    	return
  
    endif
  
    ; gets kidnapped by bandits
  
    if ( nohit )
  
    	; setting these to 0 will, counterintuitively, make them have an effect
  
    	set nohit to 0
  
    	set noattack to 0
  
    	set nothief to 0
  
    	set nointruder to 0
  
    	set noidle to 0
  
    	set noflee to 0
  
    	set nohello to 0
  
    endif
  
    ; goes to Infirmary of St. Meris after being freed
  
    short doOnce
  
    if ( doOnce == 0 )
  
    	if ( TR_m3_EEC_YontusFreed )
  
    		if ( GetDistance "TR_m3_EEC_YontusAid" < 1000 )
  
    			set sick to 1
  
    			set doOnce to 1
  
    		endif
  
    	endif
  
    endif
  
    End