TR_m3_OE_fiendchest_scr1
TR_Mainland.esm
Variables
2
Local Variables
speaktoplayer
pickedUpGem
Source
1begin TR_m3_OE_fiendchest_scr1
2
3; Script on container TR_m3_OE_fiendchest for quest
4; TR_m3_OE_Freedom.
5
6short speaktoplayer
7short pickedUpGem
8
9; set randomizer global if not set
10if ( TR_m3_fiendrandomizer_glb == 0 )
11 set TR_m3_fiendrandomizer_glb to ( Random, 3 )
12 set TR_m3_fiendrandomizer_glb to ( TR_m3_fiendrandomizer_glb + 1 ) ; 0 is unset, so your range is really 1-3
13endif
14
15; enable if you've hit the lucky number
16if ( TR_m3_fiendrandomizer_glb != 1 )
17 if ( GetDisabled == 0 )
18 Disable
19 endif
20 return
21elseif ( GetDisabled )
22 Enable
23endif
24
25; opened with telekinesis, with GetDistance player > 200
26if ( OnActivate )
27 if ( GetLocked == 0 )
28 if ( GetJournalIndex "TR_m3_OE_Freedom" < 20 )
29 Messagebox "I have waited a long time for this moment. A vile warrior imprisoned me in this gem. I cannot remember my true form, or even my name. Remove me from this chest and help me seek vengeance."
30 PlaySound "T_SndObj_Hauntedfade"
31 Journal TR_m3_OE_Freedom 20
32 endif
33 endif
34 Activate
35endif
36
37if ( GetJournalIndex "TR_m3_OE_Freedom" < 20 )
38 if ( GetDistance player <= 200 )
39 Messagebox "I have waited a long time for this moment. A vile warrior imprisoned me in this gem. I cannot remember my true form, or even my name. Remove me from this chest and help me seek vengeance."
40 PlaySound "T_SndObj_Hauntedfade"
41 Journal TR_m3_OE_Freedom 20
42 endif
43endif
44
45if ( GetJournalIndex "TR_m3_OE_Freedom" == 20 )
46 if ( pickedUpGem == 0 )
47 if ( player->GetItemCount "TR_m3_OE_fiendgem" > 0 )
48 StartScript "TR_m3_OE_fiendgem_scr"
49 set pickedUpGem to 1
50 endif
51 endif
52endif
53
54if ( pickedUpGem == 0 )
55 if ( CellChanged )
56 set speaktoplayer to 0
57 elseif ( speaktoplayer == 0 )
58 if ( GetDistance player <= 500 )
59 Messagebox "...in...here..."
60 set speaktoplayer to 1
61 endif
62 endif
63endif
64
65end