TR_m3_bloodstonestrips_scr
TR_Mainland.esm
Variables
11
Local Variables
playerrunning
playerjumping
playermoved
rockmessage
startpilgrimage
endpilgrimage
playerposx
playerposy
playerpreviousx
playerpreviousy
timer
Source
1begin TR_m3_bloodstonestrips_scr
2
3; Script on clothing TR_m3_bloodstonestrips
4; for the Bloodstone Pilgrimage quest (TR_m3_TT_Bloodstone).
5; This does the same as TR_m3_bloodstoneshoes_scr, but for beast races.
6
7float playerposx
8float playerposy
9float playerpreviousx
10float playerpreviousy
11short playerrunning
12short playerjumping
13short playermoved
14short rockmessage
15short startpilgrimage ;change this to a global, have the shrine check it when you're close
16short endpilgrimage
17float timer
18
19if ( MenuMode )
20 return
21endif
22
23if ( endpilgrimage )
24 return
25endif
26
27if ( player->HasItemEquipped, "TR_m3_bloodstonestrips" == 0 )
28 set TR_m3_bloodstonecheck to 0
29 set rockmessage to 0
30 return
31endif
32
33if ( GetJournalIndex TR_m3_TT_Bloodstone >= 70 )
34 set endpilgrimage to 1
35endif
36
37if ( GetPCCell, "Almas Thirr, Hetman Llothro's House" )
38 if ( TR_m3_bloodstonecheck == 0 )
39 ;messagebox "pilgrimage start"
40 set TR_m3_bloodstonecheck to 1
41 endif
42endif
43
44if ( player->GetEffect, sEffectLevitate == 1 )
45 ;MessageBox "I'm levitating"
46 return
47endif
48
49if ( GetPCJumping )
50 set playerjumping to 1
51else
52 if ( playerjumping )
53 Messagebox "You feel a sharp pain in your foot."
54 player->ModCurrentHealth -5
55 player->ModCurrentFatigue -5
56 endif
57 set playerjumping to 0
58endif
59
60if ( GetPCRunning )
61 set playerrunning to 1
62else
63 set playerrunning to 0
64endif
65
66set playerpreviousx to playerposx
67set playerpreviousy to playerposy
68
69set playerposx to ( player->GetPos, X )
70set playerposy to ( player->GetPos, Y )
71
72if ( playerposx != playerpreviousx )
73 set playermoved to 1
74else
75 if ( playerposy != playerpreviousy )
76 set playermoved to 1
77 else
78 set playermoved to 0
79 endif
80endif
81
82if ( playermoved )
83 if ( rockmessage == 0 )
84 Messagebox "You feel sharp glass in the cloth dig into your foot."
85 set rockmessage to 1
86 endif
87 set timer to ( timer + GetSecondsPassed )
88 if ( timer > 1 )
89 player->ModCurrentHealth -1
90 player->ModCurrentFatigue -2
91 if ( playerrunning )
92 player->ModCurrentHealth -5
93 player->ModCurrentFatigue -2
94 endif
95 set timer to 0
96 endif
97endif
98
99end