Script
TR_m3_q_3_Burglar_sc

TR_Mainland.esm
Variables 21
Local Variables
TR_Map
NoLore
state
dead
IntimidatingPC
hisDisposition
greetonce
commanded
DoorIsOpen
FadeToBlack
PCResting
knockingout
restrainattempt
button
T_Local_NPC
T_Local_NoLore
TheTime
LookAtTheTime
timer
unlocktimer
paralysetimer
Source
  
    Begin TR_m3_q_3_Burglar_sc
  
    ;script on the copy of Balamus Arthre placed into the Vault during the burglary
  
    ;WARNING: script seems to somehow stretch capacity for potential operations considered per frame?
  
    ;some seemingly superfluous Returns or duplicatas are there to avoid this
  
    ;might still be places where adding any line at all would result in immediate left eval
  
    short TR_Map
  
    short NoLore
  
    short state
  
    short dead
  
    short IntimidatingPC
  
    short hisDisposition
  
    short greetonce
  
    short commanded
  
    short DoorIsOpen
  
    short FadeToBlack
  
    short PCResting
  
    float TheTime
  
    float LookAtTheTime
  
    float timer
  
    float unlocktimer
  
    short knockingout
  
    float paralysetimer
  
    short restrainattempt
  
    short button
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    If ( GetDisabled == 1 )
  
    	SetDelete 1
  
    	Return
  
    Endif
  
    If ( CellChanged == 1 )										;make sure he doesn't stay stuck in the cell
  
    	Disable
  
    	Return
  
    Endif
  
    ;----------- Death
  
    If ( dead == 1 )
  
    	Return
  
    ElseIf ( OnDeath == 1 )
  
    	set dead to 1
  
    	set TR_m3_q_3_thieving to 2
  
    	If ( GetJournalIndex "TR_m3_Bo_Burglar2" < 95 )
  
    		Journal "TR_m3_Bo_Burglar2" 42
  
    	Endif
  
    	Return
  
    Endif
  
    ;----------- Detect player loitering 
  
    ;----------- (alternative solution= place 'enemies nearby' while the thief is inside so you can't rest?)
  
    If ( TheTime == 0 )
  
    	set TheTime to GameHour
  
    Endif
  
    If ( MenuMode == 1 )
  
    	set LookAtTheTime to ( GameHour - TheTime )
  
    	if ( LookAtTheTime > 0.5 )								;before the usual return, check if time jumps while in MenuMode
  
    		set PCResting to 1									;if so it means the player's resting
  
    	elseif ( LookAtTheTime < -0.5 )
  
    		set PCResting to 1
  
    	else
  
    		set PCResting to 0
  
    	endif
  
    	If ( PCResting == 1 )
  
    		If ( GetJournalIndex "TR_m3_Bo_Burglar2" < 40 )
  
    			If ( GameHour >= 20 )								;in case the PC starts resting (loitering) AFTER this NPC is placed,
  
    				set TR_m3_q_3_thieving to 0				;he shant be hanging around any longer
  
    				set dead to 1
  
    				Disable
  
    			Endif
  
    		Endif
  
    	Endif
  
    	Return
  
    Endif
  
    set TheTime to GameHour
  
    ;----------- Capture by knock-down
  
    If ( GetJournalIndex "TR_m3_Bo_Burglar2" < 41 )
  
    	If ( knockingout == 1 )
  
    		set paralysetimer to ( paralysetimer + GetSecondsPassed )
  
    		If ( paralysetimer > 1 )
  
    			set paralysetimer to 0
  
    			Journal "TR_m3_Bo_Burglar2" 41
  
    			set TR_m3_q_3_thieving to 3
  
    			StopCombat
  
    			SetFight 30
  
    			AiWander 0, 0, 0	
  
    			Set FadeToBlack to 1
  
    			Return
  
    		Endif
  
    	ElseIf ( OnKnockout == 1 )
  
    		set paralysetimer to 0
  
    		set knockingout to 1
  
    		ModCurrentFatigue -200
  
    ;----------- Capture by paralysis
  
    	ElseIf ( GetParalysis == 1 )								;he's captured if paralysed more than 8 seconds, or more than 2 with a STR+h2h check
  
    		If ( restrainattempt >= 0 )
  
    			set paralysetimer to ( paralysetimer + GetSecondsPassed )
  
    			If ( restrainattempt == 0 )
  
    				If ( paralysetimer > 2 )
  
    					MessageBox "He's paralyzed!", "Keep fighting", "Get close and try to restrain him"
  
    					set restrainattempt to 1
  
    				Endif
  
    			ElseIf ( restrainattempt == 1 )
  
    				set button to GetButtonPressed
  
    				If ( button == -1 )
  
    					Return
  
    				ElseIf ( button == 0 )
  
    					set restrainattempt to -1
  
    					Return
  
    				ElseIf ( button == 1 )
  
    					set restrainattempt to 2
  
    					Return
  
    				Endif
  
    			ElseIf ( restrainattempt == 2 )
  
    				If ( paralysetimer > 6 )
  
    					Journal "TR_m3_Bo_Burglar2" 41	;long enough, gets captured
  
    					set TR_m3_q_3_thieving to 3
  
    					StopCombat
  
    					SetFight 30
  
    					AiWander 0, 0, 0	
  
    					Set FadeToBlack to 1
  
    					SetParalysis 1
  
    					Return
  
    				Endif
  
    			Endif
  
    		Endif
  
    	ElseIf ( restrainattempt == 2 )							;paralysis ends while trying to restrain him
  
    		If ( GetDistance, player <= 100 )
  
    			set restrainattempt to ( player->GetLevel + GetHandToHand )
  
    			If ( restrainattempt >= 80 )
  
    				set restrainattempt to 3						;if strong enough, gets captured...
  
    				MessageBox, "You manage to restrain him."
  
    			Else
  
    				Set restrainattempt to -1
  
    				MessageBox, "He breaks free!"
  
    				Say, "vo\d\m\Atk_DM006.mp3", "ARRRR!"
  
    			Endif
  
    		Endif
  
    	ElseIf ( restrainattempt == 3 )							;...is captured
  
    		Journal "TR_m3_Bo_Burglar2" 41
  
    		set TR_m3_q_3_thieving to 3
  
    		StopCombat
  
    		SetFight 30
  
    		AiWander 0, 0, 0	
  
    		Set FadeToBlack to 1
  
    		Return
  
    	ElseIf ( paralysetimer > 0 )
  
    		Set paralysetimer to 0
  
    	Endif
  
    Endif
  
    ;----------- Capture by command
  
    If ( GetEffect, sEffectCommandHumanoids == 1 )
  
    	set commanded to 1											;used in dialogue
  
    ElseIf ( commanded == 1 )
  
    	set commanded to 0
  
    Endif
  
    ;----------- Ellipsis after capturing him
  
    If ( FadeToBlack == 1 )
  
    	If ( GameHour > 22 )											;cancel in the unlikely case that the thievery was stretched for hours and the capn's already in
  
    		Set FadeToBlack to 0
  
    	Else
  
    		DisablePlayerControls
  
    		FadeOut 0.8
  
    		set timer to 0
  
    		set FadeToBlack to 2
  
    	Endif
  
    ElseIf ( FadeToBlack == 2 )
  
    	set timer to ( timer + GetSecondsPassed )
  
    	If ( timer > 1 )
  
    		set GameHour to 21.999									;cut to the Captain entering
  
    		set FadeToBlack to 3
  
    	Endif
  
    ElseIf ( FadeToBlack == 3 )
  
    	set timer to ( timer + GetSecondsPassed )
  
    	If ( timer > 2 )
  
    		;EnablePlayerControls									;4o4 player controls stay disabled to prevent them from leaving before his dialogue
  
    		FadeIn 0.8
  
    		set FadeToBlack to 4
  
    	Endif
  
    Endif
  
    ;----------- Movement AI
  
    If ( GetJournalIndex "TR_m3_Bo_Burglar2" < 40 )
  
    	If ( TR_m3_q_3_thieving == 1 )								;set by the global script when he enters		-unnecessary now that he's a copy NPC!
  
    		If ( state == 0 )
  
    			set hisDisposition to ( TR_m3_Balamus_Arthre->GetDisposition )
  
    			set hisDisposition to ( hisDisposition - GetDisposition )
  
    			ModDisposition hisDisposition
  
    			set IntimidatingPC to ( player->GetLevel + GetStrength )
  
    			if ( IntimidatingPC >= 90 )
  
    				set IntimidatingPC to 1							;used in dialogue
  
    			else
  
    				set IntimidatingPC to 0
  
    			endif
  
    			PlaySound3D "Wooden Door Open 1"
  
    			MessageBox, "You hear a muffled noise coming from the entrance."
  
    			ForceSneak
  
    			Cast, "TR_m3_q_3_Burglar_sp", "TR_m3_q_3_Burglar"
  
    			set state to 1
  
    		ElseIf ( state == 1 )										;wait while he casts invisibility on himself
  
    			set timer to ( timer + GetSecondsPassed )
  
    			If ( timer > 2 )
  
    				AiTravel 4400, 4200, 12350, 1					;walks to the door
  
    				set state to 2
  
    				set timer to 0
  
    			Endif
  
    		ElseIf ( state == 2 )
  
    			If ( "TR_m3_q_3_VaultDoor02".isOpen == 1 )		;if it's already open, or PC opens it now, he'll run away
  
    				set timer to ( timer + GetSecondsPassed )
  
    				If ( timer > 1 )
  
    					AiTravel 3800, 3845, 12350, 1
  
    					set state to 6
  
    				Endif
  
    			Endif
  
    			If ( GetAIPackageDone == 1 )
  
    				If ( "TR_m3_q_3_VaultDoor02"->GetLocked == 1 )
  
    					AiWander 0 0 0 0 0 0 0 0 0
  
    					set unlocktimer to 0.1							;starts unlocking
  
    					"TR_m3_q_3_VaultDoor02"->PlaySound3D "Open Lock"
  
    				Else													;if it was already unlocked, he smells a rat when opening it and heads back out
  
    					Set "TR_m3_q_3_VaultDoor02".beOpen to 1
  
    					AiTravel 3800, 3845, 12350, 1
  
    					set state to 6
  
    				Endif
  
    			Endif
  
    			If ( unlocktimer > 0 )
  
    				set unlocktimer to ( unlocktimer + GetSecondsPassed )
  
    				if ( unlocktimer > 2 )
  
    					"TR_m3_q_3_VaultDoor02"->PlaySound3D "Open Lock"
  
    					"TR_m3_q_3_VaultDoor02"->Unlock			;opens it
  
    					Set "TR_m3_q_3_VaultDoor02".beOpen to 1
  
    					set state to 3
  
    				endif
  
    			Endif
  
    		ElseIf ( state == 3 )
  
    			If ( "TR_m3_q_3_VaultDoor02".isOpen == 0 )
  
    			Else														;have to condition it in that contrived way or it crashes. (?_?) - aitravel gets called on door?
  
    				AiTravel 3850, 4400, 12086, 1					;walks a bit down there
  
    				set state to 4
  
    			Endif
  
    		ElseIf ( state == 4 )
  
    			If ( GetAIPackageDone == 1 )
  
    				AiTravel 4380, 4400, 12350, 1					;sees there are people inside too, doubles back up
  
    				set state to 5
  
    			Endif
  
    		ElseIf ( state == 5 )
  
    			If ( GetAIPackageDone == 1 )
  
    				AiTravel 3800, 3845, 12350, 1					;goes back to the entrance
  
    				set state to 6
  
    			Endif
  
    		ElseIf ( state == 6 )
  
    			If ( GetAIPackageDone == 1 )						;and, if uninterrupted so far, leaves
  
    				set state to 7							
  
    				set TR_m3_q_3_thieving to 0
  
    				set dead to 1
  
    				Disable												;we're done with this copy of the NPC
  
    			Endif
  
    		Endif
  
    	Endif
  
    Endif
  
    If ( GetJournalIndex "TR_m3_Bo_Burglar2" >= 100 )		;the captain's come to take him away
  
    	If ( state < 8 )
  
    		RemoveSpellEffects, "TR_m3_q_3_Burglar_sp"
  
    		SetParalysis 0												;get back up if necessary
  
    		SetFatigue 200
  
    		ClearForceSneak
  
    		AiTravel 3800, 3845, 12350, 1							;goes back to the entrance
  
    		set state to 8
  
    	ElseIf ( state == 8 )
  
    		If ( GetAIPackageDone == 1 )
  
    			set state to 9
  
    			Disable													;he leaves
  
    		Endif
  
    	Endif
  
    Endif
  
    ; regional filter & nolore
  
    if ( TR_Map == 3 )
  
    	return
  
    endif
  
    set TR_Map to 3
  
    End