Script
TR_m7_HH_Alvynu2_Clerk_scr

TR_Mainland.esm
Variables 6
Local Variables
TR_Map
control
T_Local_NPC
T_Local_NoLore
NoLore
TR_m7_Ns_HH_Clerk
Source
  
    begin TR_m7_HH_Alvynu2_Clerk_scr
  
    ;This script makes the clerks nolore and lowers their disposition when Q2 of the narsis HH questline starts
  
    ;Nolore gets unset after the end of the quest but disposition is *not* increased
  
    short TR_Map
  
    short control
  
    ; 0 = not initialized
  
    ; 1 = initialized
  
    ; 2 = quest started
  
    ; 3 = quest ended
  
    ; control is being used instead of controlq
  
    ; because saravi already uses controlq and
  
    ; I wanted to keep it consistent between the scripts
  
    short T_Local_NPC
  
    short T_Local_NoLore
  
    short NoLore
  
    ; for dialogue filtering so the validator doesnt yell at me
  
    short TR_m7_Ns_HH_Clerk
  
    if ( OnDeath == 1 )
  
    	if ( GetJournalIndex TR_m7_HH_Alvynu_2 > 0 )
  
    		if ( GetJournalIndex TR_m7_HH_Alvynu_2 < 100 )
  
    			set TR_m7_HH_Alvynu2_Murder to 1
  
    		endif
  
    	endif
  
    endif
  
    if ( control == 3 )
  
    	return
  
    endif
  
    if ( control == 0 )
  
    	set TR_Map to 7
  
    	set T_Local_NoLore to 1
  
    	set control to 1
  
    endif
  
    if ( control == 1 )
  
    	if ( GetJournalIndex TR_m7_HH_Alvynu_2 > 0 )
  
    		moddisposition -40
  
    		set T_Local_NoLore to 0
  
    		set control to 2
  
    	endif
  
    elseif ( control == 2 )
  
    	if ( GetJournalIndex TR_m7_HH_Alvynu_2 >= 100 )
  
    		set T_Local_NoLore to 1
  
    		set control to 3
  
    	endif
  
    endif
  
    end